Change OSGI_HTTP_DYNAMIC_BUNDLES in Notes.ini from LotusScript

Option Public
Option Declare

Const W32_LIB = {nnotes.dll}
Const LINUX_LIB = {libnotes.so}
Const MAC_LIB = {libnotes.dylib}

Declare Sub W32_OSSetEnvironmentVariableExt Lib W32_LIB Alias {OSSetEnvironmentVariableExt} (ByVal varName As String, ByVal varValue As String, ByVal isSoft As Integer)
Declare Sub LINUX_OSSetEnvironmentVariableExt Lib LINUX_LIB Alias {OSSetEnvironmentVariableExt} (ByVal varName As String, ByVal varValue As String, ByVal isSoft As Integer)
Declare Sub MAC_OSSetEnvironmentVariableExt Lib MAC_LIB Alias {OSSetEnvironmentVariableExt} (ByVal varName As String, ByVal varValue As String, ByVal isSoft As Integer)

Sub Initialize
	On Error GoTo errHandler
	
	SetEnvironmentValue "OSGI_HTTP_DYNAMIC_BUNDLES", "dominojna_updatesite.nsf", True
	
	Exit Sub
errHandler:
	MsgBox Error() + " in line "+CStr(Erl())
	Exit sub
End Sub


Public Sub SetEnvironmentValue (varName As String, varValue As String, isSoft As Boolean)
	Dim isSoftAsInt As Integer
	
	If isSoft = True Then
		isSoftAsInt = 1
	Else
		isSoftAsInt = 0
	End If
	
    If isDefined("WINDOWS") Then
		W32_OSSetEnvironmentVariableExt varName, varValue, isSoftAsInt
    ElseIf isDefined("MAC") Then
		MAC_OSSetEnvironmentVariableExt varName, varValue, isSoftAsInt
    Else
		LINUX_OSSetEnvironmentVariableExt varName, varValue, isSoftAsInt
    End If
End Sub